#!/bin/csh -f

setenv OMP_STACKSIZE    2M
limit stacksize unlimited
setenv OMP_NUM_THREADS 4

## *** プロジェクト名 ***
set PROJECT="rotCo"
## ポテンシャルファイル名
set POTENTIAL=${PROJECT}

## *** 初期基本並進ベクトル ***
## aベクトル (1/2 -√3/2 0)
set AX0=`echo "1/2" | bc -l`
set AY0=`echo "-sqrt(3)/2" | bc -l`
set AZ0=`echo "0" | bc -l`
## bベクトル (1/2 √3/2 0)
set BX0=`echo "1/2" | bc -l`
set BY0=`echo "sqrt(3)/2" | bc -l`
set BZ0=`echo "0" | bc -l`
## cベクトル (0 0 2√2/√3)
set CX0=`echo "0" | bc -l`
set CY0=`echo "0" | bc -l`
set CZ0=`echo "2*sqrt(2)/sqrt(3)" | bc -l`

## *** 回転角度のリスト (度) ***
set DEGREE_LIST=( 0 10 20 30 40 50 60 70 80 90 )
## 円周率
set PI=`echo "4*a(1)" | bc -l`	

foreach DEGREE ( ${DEGREE_LIST} )
  ## 度からラジアンへ
  set THETA=`echo "${DEGREE}*${PI}/180" | bc -l`
  ## aベクトルの回転
  set AX=`echo "${AX0}" | bc -l`
  set AY=`echo "${AY0}*c(${THETA})-${AZ0}*s(${THETA})" | bc -l`
  set AZ=`echo "${AY0}*s(${THETA})+${AZ0}*c(${THETA})" | bc -l`
  ## bベクトルの回転
  set BX=`echo "${BX0}" | bc -l`
  set BY=`echo "${BY0}*c(${THETA})-${BZ0}*s(${THETA})" | bc -l`
  set BZ=`echo "${BY0}*s(${THETA})+${BZ0}*c(${THETA})" | bc -l`
  ## cベクトルの回転
  set CX=`echo "${CX0}" | bc -l`
  set CY=`echo "${CY0}*c(${THETA})-${CZ0}*s(${THETA})" | bc -l`
  set CZ=`echo "${CY0}*s(${THETA})+${CZ0}*c(${THETA})" | bc -l`

  ## テンプレートから入力ファイルを作成
  sed 's/'DEGREE'/'${DEGREE}'/g' template/${PROJECT}_SRA_Template.in | sed 's/'AX'/'${AX}'/g' | sed 's/'AY'/'${AY}'/g' | sed 's/'AZ'/'${AZ}'/g' | sed 's/'BX'/'${BX}'/g' | sed 's/'BY'/'${BY}'/g' | sed 's/'BZ'/'${BZ}'/g' | sed 's/'CX'/'${CX}'/g' | sed 's/'CY'/'${CY}'/g' | sed 's/'CZ'/'${CZ}'/g' > in/${PROJECT}_SRA_${DEGREE}.in
  specx < in/${PROJECT}_SRA_${DEGREE}.in > out/${PROJECT}_SRA_${DEGREE}.out
  sed 's/'DEGREE'/'${DEGREE}'/g' template/${PROJECT}_SRALS_Template.in | sed 's/'AX'/'${AX}'/g' | sed 's/'AY'/'${AY}'/g' | sed 's/'AZ'/'${AZ}'/g' | sed 's/'BX'/'${BX}'/g' | sed 's/'BY'/'${BY}'/g' | sed 's/'BZ'/'${BZ}'/g' | sed 's/'CX'/'${CX}'/g' | sed 's/'CY'/'${CY}'/g' | sed 's/'CZ'/'${CZ}'/g' > in/${PROJECT}_SRALS_${DEGREE}.in
  specx < in/${PROJECT}_SRALS_${DEGREE}.in > out/${PROJECT}_SRALS_${DEGREE}.out
end